Structural Reference Experiment

From OWL

Jump to: navigation, search

Editor's Note: This is an experimental version of the syntax document to make it able to serve the role of a descriptive specification, thus taking over the role of the reference and overview from OWL 1.0. If you haven't already talked with Bijan, Boris, or Peter, please check with one of them before making a radical *structural* change. Otherwise, feel free to add examples, or leave comments.

Hide Review Comments

Hide UML

Hide Grammar

Document title:
OWL 1.1 Web Ontology Language
Structural Specification and Functional-Style Syntax


[edit] 1 Preliminaries

Editor's Note: I didn't include all the namespace et al for spec experimentation reasons -- BJP

In this specification, OWL ontologies are defined in ways intended to be, on the one hand, largely independant of the concrete exchange syntaxes, and yet, on the other, sufficient for the clear specification of those syntaxes. There are several reasons for this stemming from the fact that some exchange syntaxes (e.g., the canonical RDF/XML) make it difficult to relate OWL to the canonical underlying formalisms (i.e., description logics or first order logic). Defining the semantics directly in terms of such syntaxes would make it much more difficult to understand OWL by making the large literature available on the underlying formalisms more inaccessible. Similarly, in order to assure decidability (or, in some fragments, polynomial decidability), certain "non-structural" restrictions on axioms need to be imposed. It is very difficult to clearly and correctly impose these directly on triple structures. Finally, a number of OWL tools, APIs, and concrete syntaxes work at a non-triple level. Given the need to clearly map OWL into terms that make sense for these cases, and the difficulty of several specification tasks when approached from the RDF perspective, OWL is defined first in terms of non-triple structural form.

In order to determine the particular concrete syntax for some bit of OWL, one should consult the corresponding mapping tables in the corresponding documents. The primary structural specification is in terms of UML diagrams given in this document, with a canonical functional syntax which instantiates the UML. For reader convenient, you may choose to hide the diagrams, or the grammar, or both.

Conceptually, OWL ontologies can be broken down into the following categories of parts:

  • entities --- classes, properties, individuals, etc.; syntactically, these are the sorts of things which are named by URIs; they can be thought of as primitive terms or names;
  • expressions --- these are descriptive characterizations of entities; e.g., a class expression defines a class, typically in terms of features of its possible instances, i.e., descriptions of the sort of thing which are members of that class; obviously, expressions are parameterized by the sort of entity they characterize, thus we have class expressions, or property expressions; different sorts of expression have richer or poorer support in OWL; for example, OWL has a rather rich class expression functionality but comparatively poor property expressions;
  • axioms --- these make statements, i.e., true or false assertions that relate entities or expressions with other entities or expressions.

These three categories form the logical part of OWL ontologies. Additionally, entities, axioms, and ontologies may be annotated. Annotations have no effect on the logical aspects of an ontology, though they may be significant to tools or critical for applications. In many cases, the point of the logical portion of an ontology is to support the exploitation of the annotation part. The significance of annotations on tools or applications is not defined by the OWL specifications.

Finally, there is one non-logical construct with a pre-defined meaning, owl:imports, which allows distinct ontologies to be combined.

In concrete syntaxes, there may be additional syntactic features such as mechanisms for abbreviating URIs.

[edit] 2 Ontologies

Ontologies are the basic structure in OWL. They primarily consist of a set of assertions about the world and may include assertions from other, imported, ontologies.

OWL Ontologies
Figure 1. OWL Ontologies

[edit] 2.1 Syntax

The syntax for OWL 1.1 ontology files is defined as follows:

ontologyFile := { namespace } ontology
namespace := 'Namespace' '(' [ prefix ] '=' Full-IRI ')'
ontology := 'Ontology' '(' ontologyURI { importDeclaration } { annotation } { axiom } ')'
ontologyURI := URI
importDeclaration := 'Import' '(' URI ')'
axiom := classAxiom | objectPropertyAxiom | dataPropertyAxiom | fact | declaration | entityAnnotation

The namespace production defines an abbreviation for namespaces in a document. In each document, only one namespace declaration can exist for a given prefix. These prefixes are then used to expand abbreviated IRIs as specified in Section 2.2.

[edit] 2.2 Ontology URIs

The structure of OWL 1.1 ontologies is shown in Figure 1. Each ontology is uniquely identified with an ontology URI. This URI need not be equal to the physical location of the ontology file. For example, a file for an ontology with a URI need not be physically stored in that location. A specification of a mechanism for physically locating an ontology from its ontology URI is not in scope of this specification.

[edit] 2.3 Axioms

The main component of an OWL 1.1 ontology is the set of axioms that it contains. Note that this definition does not allow repetitions of structurally equivalent axioms in an ontology. OWL 1.1 ontology files are, however, not expected to enforce this and can simply eliminate duplicates.

[edit] 2.4 Ontology Annotations

Apart from a set of axioms, an OWL 1.1 ontology contains a set of annotations. These can be used to associate information with an ontology, such as the name of the ontology creator or the version of the ontology. For the purpose of annotations, and ontology can be thought as a kind of axiom

[edit] 2.5 Imports

In OWL 1.0, owl:imports was a special annotation URI, which denotes that an ontology imports another ontology. In OWL 1.1, imports are not ontology annotations, but are a separate primitive, as discussed next; the owl:imports annotation property has no built-in meaning.

Each ontology contains a possibly empty set of import declarations. An ontology O directly imports an ontology O' if O contains an import declaration whose value is the ontology URI of O'. The relation imports is defined as a transitive closure of the relation directly imports. The axiom closure of an ontology O is the smallest set containing all the axioms of O and of all ontologies that O imports. Intuitively, an import declaration specification states that, when reasoning with an ontology O, one should consider not only the axioms of O, but the entire axiom closure of O.

[edit] 2.6 Example

        Label("The example")
        SubClassOf(Human Animal)

[edit] 3 Entities

Entities are the fundamental building blocks of OWL 1.1 ontologies. The description of entities (e.g., classes, properties, and individuals) and their relations is the canonical purpose of OWL 1.1 ontologies.

NOTE: For readers with a logic background, entities are the elements of the signature of an OWL ontology.

The Hierarchy of Entities in OWL 1.1
Figure 2. The Hierarchy of Entities in OWL 1.1

[edit] 3.1 Syntax

datatypeURI := URI
owlClassURI := URI
objectPropertyURI := URI
dataPropertyURI := URI
individualURI := URI entity := datatype | owlClass | objectProperty | dataProperty | individual
datatype := 'Datatype' '(' datatypeURI ')'
owlClass := 'OWLClass' '(' owlClassURI ')'
objectProperty := 'ObjectProperty' '(' objectPropertyURI ')'
dataProperty := 'DataProperty' '(' dataPropertyURI ')'
individual := 'Individual' '(' individualURI ')'

[edit] 3.2 Predefined Entities

OWL 1.1 defines several well-known entities that have the predefined semantics. These entities are identified by the following predefined URIs:

  • The class with URI owl:Thing is the set of all objects. (In DL literature this is often called the top concept.)
  • The class with URI owl:Nothing is the empty set of objects. (In DL literature this is often called the bottom concept.)
  • The unary datatype with URI rdfs:Literal is the set of all concrete objects.
  • The datatypes with URIs as mentioned in [OWL 1.1 Semantics].

OWL 1.1 uses constants to describe atomic values, such as strings or integers. These are encoded as in the Turtle specification[TURTLE].

constant := the same as the literal production in the Turtle specification [TURTLE]

[edit] 3.3 Declarations

[edit] 3.4 Annotations

[edit] 4 Expressions

Editor's Note: {{{2}}}

[edit] 5 Class Expressions

Editor's Note: See Issue-65 (excess vocab).

OWL 1.1 provides an expressive language for forming descriptions. For clarity, these are presented in three separate diagrams. Readers familiar with model theory may which to consult the Semantics Document.

Editor's Note: Would like to have more class expression specific stuff, similar to what's in the first sentence of the next section. BJP

[edit] 5.1 Propositional Connectives

Class expressions can be thought of as descriptions of sets of individuals, or as descriptions which are true (or false) of particular individuals. These descriptions can be combined in ways that produce set theoretical combination of their underlying sets (or that change the set of conditions which must be true of an instance of the combined expression). OWL 1.1 contains the standard boolean connectives, and (intersectionOf), not (complementOf), and or (unionOf).

Propositional Connectives for the Formation of Descriptions
Figure 7. Propositional Connectives for the Formation of Descriptions

The description construct objectUnionOf forms a disjunction of a set of descriptions, objectIntersectionOf is a conjunction of a set of descriptions, objectComplementOf is a negation of a description, and objectOneOf is a descrption that contains exactly the objects denoted by the set of specified individuals.

Note: The OWL 1.1 propositional connectives allow for the encoding of
propositional logic/boolean formulae (either as class expressions or
as collections of facts). Thus, reasoners which can test for class or ontology
consistency can, by means of simple translation, also test for propositional

The owl:oneOf constructor is, of course, not part of propositional logic, but
is grouped here for convenience.

[edit] 5.1.1 Syntax

objectUnionOf := 'ObjectUnionOf' '(' description description { description } ')'
objectIntersectionOf := 'ObjectIntersectionOf' '(' description description { description } ')'
objectComplementOf := 'ObjectComplementOf' '(' description ')'
objectOneOf := 'ObjectOneOf' '(' individualURI { individualURI }')'

[edit] 5.1.2 Examples

ObjectUnionOf(Male Female Intersexual) Anything which is Male, Female, or Intersexed (it is possible to be more than one)
ObjectIntersectionOf(Human, ObjectUnionOf(Male Female Intersexual)) Anything which is both Human and at least one of the sexes

[edit] 5.2 Object Value Restrictions

OWL 1.1 also allows descriptions to be defined by means of restrictions on object properties, as shown in Figure 8.

OWL 1.1 Descriptions Defined by Restriction on Object Properties
Figure 8. OWL 1.1 Classes Defined by Restriction on Object Properties

The construct objectAllValuesFrom denotes the set of objects that are connected via the given object property only to instances of the given description, objectSomeValuesFrom denotes the set of objects that are connected via the given object property to at least one instance of the given description, objectExistsSelf denotes the set of objects that are connected to themselves via the given object property, and objectHasValue denotes the set of objects that are connected via the given object property to the object denoted by the given individual. The grammar for the restrictions is as follows:

[edit] 5.2.1 Syntax

objectAllValuesFrom := 'ObjectAllValuesFrom' '(' objectPropertyExpression description ')'
objectSomeValuesFrom := 'ObjectSomeValuesFrom' '(' objectPropertyExpression description ')'
objectExistsSelf := 'ObjectExistsSelf' '(' objectPropertyExpression ')'
objectHasValue := 'ObjectHasValue' '(' objectPropertyExpression individualURI ')'

[edit] 5.2.2 Examples

[edit] 5.3 Object Cardinality Restrictions

OWL 1.1 descriptions can be defined by restricting the cardinality of associations between objects, as shown in Figure 9.

OWL 1.1 Descriptions Defined by Restricting Object Property Cardinalities
Figure 9. OWL 1.1 Descrptions Defined by Restricting Object Property Cardinalities

Cardinality restrictions can be qualified or unqualified, depending on whether there is a restriction on the description of the connected individual; an unqualified cardinality restriction is equivalent to a qualified one where the restricting description is owl:Thing. The construct objectMinCardinality denotes the set of objects that are connected via the given object property to at least the given number of instances of the given description, the construct objectMaxCardinality denotes the set of objects that are connected via the given object property to at most the given number of instances of the given description, and the description objectExactCardinality denotes the set of objects that are connected via the given object property to exactly the given number of instances of the given description. The grammar for these restrictions is defined as follows:

[edit] 5.3.1 Syntax

cardinality := nonNegativeInteger
objectMinCardinality := 'ObjectMinCardinality' '(' cardinality objectPropertyExpression [ description ] ')'
objectMaxCardinality := 'ObjectMaxCardinality' '(' cardinality objectPropertyExpression [ description ] ')'
objectExactCardinality := 'ObjectExactCardinality' '(' cardinality objectPropertyExpression [ description ] ')'

[edit] 5.3.2 Examples

[edit] 5.4 Data Value Restrictions

OWL 1.1 also allows for the definition of descriptions by stating restrictions on data properties, as shown in Figure 10.

OWL 1.1 Descriptions Defined by Restriction on Data Properties
Figure 10. OWL 1.1 Descriptions Defined by Restriction on Data Properties

The notable distinction with respect to object property restrictions is that dataAllValuesFrom and dataSomeValuesFrom restrictions take a list of data property expressions, and not just a single property expression. This is in order to support descriptions such as "objects whose width is greater than their height", where the values of width and height are specified using two data properties. In such definitions, the arity of the given data range must be equal to the number of the given data properties.

[edit] 5.4.1 Syntax

dataAllValuesFrom := 'DataAllValuesFrom' '(' dataPropertyExpression { dataPropertyExpression } dataRange ')'
dataSomeValuesFrom := 'DataSomeValuesFrom' '(' dataPropertyExpression { dataPropertyExpression } dataRange ')'
dataHasValue := 'DataHasValue' '(' dataPropertyExpression constant ')'

[edit] 5.4.2 Examples

[edit] 5.5 Data Cardinallity Restrictions

Figure 11 shows the restrictions that can be built by stating cardinality restrictions on data properties. If the data range is supplied, its arity must be one.

OWL 1.1 Descriptions Defined by Restriction on Data Properties
Figure 11. OWL 1.1 Descriptions Defined by Restriction on Data Properties

[edit] 5.5.1 Syntax

dataMinCardinality := 'DataMinCardinality' '(' cardinality dataPropertyExpression [ dataRange ] ')'
dataMaxCardinality := 'DataMaxCardinality' '(' cardinality dataPropertyExpression [ dataRange ] ')'
dataExactCardinality := 'DataExactCardinality' '(' cardinality dataPropertyExpression [ dataRange ] ')'

[edit] 5.5.2 Examples

[edit] 5.6 Summary of syntax

The following grammar production integrates all types of descriptions in OWL 1.1:

description := owlClassURI | objectUnionOf | objectIntersectionOf | objectComplementOf | objectOneOf |
    objectAllValuesFrom | objectSomeValuesFrom | objectExistsSelf | objectHasValue |
    objectMinCardinality | objectMaxCardinality | objectExactCardinality |
    dataAllValuesFrom | dataSomeValuesFrom | dataHasValue |
    dataMinCardinality | dataMaxCardinality | dataExactCardinality

[edit] 6 Object and Data Property Expressions

Editor's Note: Order of this is open. It could come before Class Expressions under the "define before you use" principle. BJP.

Object properties can be combined into more complex expressions, as show in Figure 3. In OWL 1.1, only inverse property expressions are allowed. The grammar for object property expressions is as follows:

inverseObjectProperty := 'InverseObjectProperty' '(' objectPropertyExpression ')'
objectPropertyExpression := objectPropertyURI | inverseObjectProperty

Object Property Expressions
Figure 3. Object Property Expressions

For symmetry, OWL 1.1 also allows for data property expressions, as shown in Figure 4; the only type of data property expressions are, however, data properties. The grammar for data property expressions is as follows:

dataPropertyExpression := dataPropertyURI

Data Property Expressions
Figure 4. Data Property Expressions

Editor's Note: See Issue-22 (role-rule-sugar) and Issue-83 (Property Chain Axioms).

[edit] 7 Data Range Expressions

Editor's Note: Order of this is open. It could come before Class Expressions under the "define before you use" principle. BJP.

Editor's Note: See Issue-5 (n-ary datatypes), Issue-25 (values-class), Issue-29 (owl:DataRange), Issue-31 (XSD defined datatypes), Issue-53 (Linear inequality between two data types), Issue-71 (datarange language range) and Issue-74 (XSD URIs for facets).

OWL 1.1 provides several ways to define a range over data values, as shown in Figure 5. A datatype is a fundamental type of data range that is defined by a URI. Each datatype URI is associated with a predefined arity (note that the same datatype URI cannot be used with different arities). The list of the datatypes supported in OWL 1.1 is given in [OWL 1.1 Semantics]; furthermore, this list can be extended by implementations as needed. The meanining of OWL 1.1 ontologies containing a datatype URI not supported by an implementation is not defined by this specification; the implementations are allowed to signal an error in this case.

Complex data ranges can be constructed from the simpler ones using the dataComplementOf constructor, which takes a data range and returns its complement (with the same arity), Furthermore, data ranges consisting exactly of the specified set of constants can be formed using the dataOneOf constructor (and it has the arity one). Finally, the datatypeRestriction constructor creates a data range by applying one or more facet restriction to a particular data range. A facet restriction consists of a constant restriction value and a facet type that is applied to the data range in question. The following facet types are supported in OWL 1.1: length, minLength, maxLength, pattern, minInclusive, minExclusive, maxInclusive, maxExclusive, totalDigits, and fractionDigits. The semantics of the facets is defined in the XML Schema Datatypes Specification [XML Schema Datatypes].

Review comment from MikeSmith 06:44, 26 November 2007 (EST)
Text addressing ISSUE-31: "Canonical URI for externally defined datatypes" is provided on the discussion page and proposed for inclusion here.

Data Ranges of OWL 1.1
Figure 5. Data Ranges of OWL 1.1

The grammar for OWL 1.1 data ranges is as follows:

dataComplementOf := 'DataComplementOf' '(' dataRange ')'
dataOneOf := 'DataOneOf' '(' constant { constant } ')'
datatypeFacet :=
    'length' | 'minLength' | 'maxLength' | 'pattern' |
    'minInclusive' | 'minExclusive' | 'maxInclusive' | 'maxExclusive' |
    'totalDigits' | 'fractionDigits'
restrictionValue := constant
datatypeRestriction := 'DatatypeRestriction' '(' dataRange datatypeFacet restrictionValue { datatypeFacet restrictionValue } ')'
dataRange := datatypeURI | dataComplementOf | dataOneOf | datatypeRestriction

[edit] 8 Axioms

This section lists the types of axiom that can be stated in OWL 1.1. To make the presentation easier to follow, the axioms are grouped by type. As already mentioned, an axiom may contain an arbitrary number of annotations; furthermore, although annotations do not affect the semantics of an axiom, they are taken into account in the definition of structural equivalence.

[edit] 8.1 Class Axioms

The class or description axioms of OWL 1.1 are shown in Figure 12. The subClassOf axiom states that one description is a subclass of another description. The equivalentClasses axiom takes a set of descriptions and states that they are all equivalent. The disjointClasses axiom takes a set of descriptions and states that all descriptions from the set are pair-wise disjoint. Finally, the disjointUnion axiom defines a class as a union of descriptions, all of which are pair-wise disjoint. The grammar for the class or description axioms of OWL 1.1 is as follows.

subClass := description
superClass := description
subClassOf := 'SubClassOf' '(' { annotation } subClass superClass ')'
equivalentClasses := 'EquivalentClasses' '(' { annotation } description description { description } ')'
disjointClasses := 'DisjointClasses' '(' { annotation } description description { description } ')'
disjointUnion := 'DisjointUnion' '(' { annotation } owlClassURI description description { description } ')'
classAxiom := subClassOf | equivalentClasses | disjointClasses | disjointUnion

The Class Axioms of OWL 1.1
Figure 12. The Class Axioms of OWL 1.1

[edit] 8.2 Object Property Axioms

OWL 1.1 provides for several different kinds of object property axioms. For clarity these are presented in two separate diagrams, the first of which is Figure 13. The equivalentObjectProperties axiom takes a set of object properties and states that they are all equivalent, and the disjointObjectProperties axiom takes a set of object properties and states that all properties from the set are pair-wise disjoint. Furthermore, objectPropertyDomain and objectPropertyRange specify the domain and the range description, respectively, of an object property. Finally, inverseObjectProperties axiomatizes two properties to be inverse of each other. These axioms are described using the following grammar:

subObjectPropertyExpression := objectPropertyExpression | 'SubObjectPropertyChain' '(' objectPropertyExpression objectPropertyExpression { objectPropertyExpression } ')'
subObjectPropertyOf := 'SubObjectPropertyOf' '(' { annotation } subObjectPropertyExpression objectPropertyExpression ')'
equivalentObjectProperties := 'EquivalentObjectProperties' '(' { annotation } objectPropertyExpression objectPropertyExpression { objectPropertyExpression } ')'
disjointObjectProperties := 'DisjointObjectProperties' '(' { annotation } objectPropertyExpression objectPropertyExpression { objectPropertyExpression } ')'
objectPropertyDomain := 'ObjectPropertyDomain' '(' { annotation } objectPropertyExpression description ')'
objectPropertyRange := 'ObjectPropertyRange' '(' { annotation } objectPropertyExpression description ')'
inverseObjectProperties := 'InverseObjectProperties' '(' { annotation } objectPropertyExpression objectPropertyExpression ')'

Object Property Axioms, Part I
Figure 13. Object Property Axioms, Part I

In addition, OWL 1.1 provides for axioms that allow the assertion of various characteristics of an object property, as specified in Figure 14. Each of these axioms takes an object property and asserts that the property has a certain characteristic, such as being functional or transitive. These axioms are described by the following grammar:

functionalObjectProperty := 'FunctionalObjectProperty' '(' { annotation } objectPropertyExpression ')'
inverseFunctionalObjectProperty := 'InverseFunctionalObjectProperty' '(' { annotation } objectPropertyExpression ')'
reflexiveObjectProperty := 'ReflexiveObjectProperty' '(' { annotation } objectPropertyExpression ')'
irreflexiveObjectProperty := 'IrreflexiveObjectProperty' '(' { annotation } objectPropertyExpression ')'
symetricObjectProperty := 'SymmetricObjectProperty' '(' { annotation } objectPropertyExpression ')'
asymetricObjectProperty := 'AsymmetricObjectProperty' '(' { annotation } objectPropertyExpression ')'
transitiveObjectProperty := 'TransitiveObjectProperty' '(' { annotation } objectPropertyExpression ')'

Axioms Defining Characteristics of Object Properties, Part II
Figure 14. Axioms Defining Characteristics of Object Properties, Part II

The following grammar production merges all productions for object property axioms:

objectPropertyAxiom :=
    subObjectPropertyOf | equivalentObjectProperties |
    disjointObjectProperties | inverseObjectProperties |
    objectPropertyDomain | objectPropertyRange |
    functionalObjectProperty | inverseFunctionalObjectProperty |
    reflexiveObjectProperty | irreflexiveObjectProperty |
    symetricObjectProperty | asymetricObjectProperty |

[edit] 8.3 Data Property Axioms

Editor's Note: See Issue-8 (dataproperty chains).

Data property axioms are similar to object property axioms, and are shown in Figure 15. Note that the arity of the data range used in a dataPropertyRange axiom must be one. The axioms are described by the following grammar:

subDataPropertyOf := 'SubDataPropertyOf' '(' { annotation } dataPropertyExpression dataPropertyExpression ')'
equivalentDataProperties := 'EquivalentDataProperties' '(' { annotation } dataPropertyExpression dataPropertyExpression { dataPropertyExpression } ')'
disjointDataProperties := 'DisjointDataProperties' '(' { annotation } dataPropertyExpression dataPropertyExpression { dataPropertyExpression } ')'
dataPropertyDomain := 'DataPropertyDomain' '(' { annotation } dataPropertyExpression description ')'
dataPropertyRange := 'DataPropertyRange' '(' { annotation } dataPropertyExpression dataRange ')'
functionalDataProperty := 'FunctionalDataProperty' '(' { annotation } dataPropertyExpression ')'

Data Property Axioms of OWL 1.1
Figure 15. Data Property Axioms of OWL 1.1

The following grammar production merges all productions for data property axioms:

dataPropertyAxiom :=
    subDataPropertyOf | equivalentDataProperties | disjointDataProperties |
    dataPropertyDomain | dataPropertyRange | functionalDataProperty

[edit] 8.4 Facts

Editor's Note: See Issue-3 (anonymous individuals) and Issue-23 (scoped-names).

OWL 1.1 supports a rich set of axioms for stating facts. Figure 16 shows the facts that can be stated about individuals and descriptions. The sameIndividual axiom states that each of the individuals from a given set denotes the same object, whereas the differentIndividuals axiom states that each of the individuals from a given set denotes a different object. The classAssertion axiom states that the object denoted by the given individual is an instance of the given description. The grammar for these axioms is as follows:

sameIndividual := 'SameIndividual' '(' { annotation } individualURI individualURI { individualURI } ')'
differentIndividuals := 'DifferentIndividuals' '(' { annotation } individualURI individualURI { individualURI } ')'
classAssertion := 'ClassAssertion' '(' { annotation } individualURI description ')'

Figure 16. Facts

The facts about object properties are shown in Figure 17. The objectPropertyAssertion states that the objects denoted by the given individuals are connected by the given property, whereas the negativeObjectPropertyAssertion states that the objects denoted by the given individuals are not connected by the given property. The grammar for these axioms is as follows:

sourceIndividualURI := individualURI
targetIndividualURI := individualURI
objectPropertyAssertion := 'ObjectPropertyAssertion' '(' { annotation } objectPropertyExpression sourceIndividualURI targetIndividualURI ')'
negativeObjectPropertyAssertion := 'NegativeObjectPropertyAssertion' '(' { annotation } objectPropertyExpression sourceIndividualURI targetIndividualURI ')'

Object Property Assertions
Figure 17. Object Property Assertions

The structure of axioms asserting facts about data properties is similar and is shown in Figure 18. The dataPropertyAssertion states that the value of a data property for an object denoted by the given individual is the given constant, whereas the negativeDataPropertyAssertion states the opposite. The grammar is as follows:

targetValue := constant
dataPropertyAssertion := 'DataPropertyAssertion' '(' { annotation } dataPropertyExpression sourceIndividualURI targetValue ')'
negativeDataPropertyAssertion := 'NegativeDataPropertyAssertion' '(' { annotation } dataPropertyExpression sourceIndividualURI targetValue ')'

Data Property Assertions
Figure 18. Data Property Assertions

The following production integrates all types of facts:

fact := sameIndividual | differentIndividuals | classAssertion |
    objectPropertyAssertion | negativeObjectPropertyAssertion |
    dataPropertyAssertion | negativeDataPropertyAssertion

[edit] 9 Annotations

An annotation consists of an annotation URI that specifies the type of annotation and a value for the annotation. OWL 1.1 allows for two kinds of annotation values:

  • Annotation values can be constants. Note that these need not be just strings; rather, any OWL 1.1 constant can be used. For example, one can create an annotation whose value is a URI formatted according to the XML Schema xsd:anyURI type specification.
  • Annotation values can be ontology entities. Such annotations make it clearer that the value is not just some constant, but an entity from this or some other ontology.

[edit] 9.1 Entity Annotations

Editor's Note: See Issue-16 (entity annotations).

Often, it is desirable to annotate entities in an ontology; such an annotation might, for example, specify a "human-friendly" label or comment. OWL 1.1 provides entity annotations for this purpose; their structure is shown in Figure 6.

Entity Annotations in OWL 1.1
Figure 6. Entity Annotations in OWL 1.1

Note that an entity annotation axiom provides for two types of annotation -- one for the axiom itself and one for the entity. It is important to distinguish these two types of annotation: the first one refers to the axiom (e.g., says who has asserted it), whereas the second one refers to the entity itself (e.g., provides a human-friendly label). The grammar for entity annotations is as follows:

annotationsForAxiom := annotation
annotationsForEntity := annotation
entityAnnotation := 'EntityAnnotation' '(' { annotationsForAxiom } entity { annotationsForEntity } ')'

Note that the production for the entityAnnotation nonterminal requires an entity and not a URI. Thus, an OWL class should be annotated as follows:

EntityAnnotation(OWLClass(Person) Comment("The set of all humans."))

This is so that the type of the entity being annotated can easily be determined from the syntactic form of the entity annotation axiom.

[edit] 10 Nonstructural Restrictions on Axioms

As explained in [SROIQ], to obtain a decidable language, the axiom closure Ax of each OWL 1.1 ontology must obey certain nonstructural restrictions, as defined next. In this section, we assume that all object property expressions in Ax are either object properties or inverses of an object property. This can be ensured by replacing all expressions InverseObjectProperty( InverseObjectProperty(PE) ) with PE.

For an object property expression PE, the inverse property expression INV(PE) is defined as follows:

  • if PE is an object property OP, then INV(PE) = InverseObjectProperty(OP);
  • if PE is of the form InverseObjectProperty(OP) for OP an object property, then INV(PE) = OP.

An object property expression PE is composite in Ax if Ax contains an axiom of the form

  • SubObjectPropertyOf(SubObjectPropertyChain(PE1 ... PEn) PE) with n > 1, or
  • SubObjectPropertyOf(SubObjectPropertyChain(PE1 ... PEn) INV(PE)) with n > 1, or
  • TransitiveObjectProperty(PE), or
  • TransitiveObjectProperty(INV(PE)).

The object property hierarchy relation → is the smallest relation on object property expressions for which the following conditions hold (AB means that → holds for A and B):

  • if Ax contains an axiom SubObjectPropertyOf(PE1 PE2), then PE1PE2 holds; and
  • if Ax contains an axiom EquivalentObjectProperties(PE1 PE2), then PE1PE2 and PE2PE1 hold; and
  • if Ax contains an axiom InverseObjectProperties(PE1 PE2), then PE1INV(PE2) and INV(PE2)PE1 hold; and
  • if Ax contains an axiom SymmetricObjectProperty(PE), then PEINV(PE) holds; and
  • if PE1PE2 holds, then INV(PE1)INV(PE2) holds as well.

The relation →* is the reflexive-transitive closure of →. An object property expression PE is simple in Ax if, for each object property expression PE' such that PE'* PE holds, PE' is not composite.

The axioms Ax satisfy the nonstructural restrictions of OWL 1.1 if the following three conditions hold:

  • Each class in Ax of the following form contains only simple object properties:
    • ObjectMinCardinality, ObjectMaxCardinality, ObjectExactCardinality, and ObjectExistsSelf.
  • Each axiom in Ax of the following form contains only simple object properties:
    • FunctionalObjectProperty, InverseFunctionalObjectProperty, IrreflexiveObjectProperty, AsymmetricObjectProperty, and DisjointObjectProperties.
  • A strict partial order < on the object property expressions must exist that fulfills the following conditions:
    • If x < y holds, then y →* x does not hold;
    • Each axiom in Ax of the form SubObjectPropertyOf(SUB PE) where SUB is of the form SubObjectPropertyChain(PE1 ... PEn) with n ≥ 2 fulfils the following conditions:
      • n = 2 and PE1 = PE2 = PE, or
      • PEi < PE for each 1 ≤ i ≤ n, or
      • PE1 = PE and PEi < PE for each 2 ≤ i ≤ n, or
      • PEn = PE and PEi < PE for each 1 ≤ i ≤ n-1.

[edit] 11 Declarations and Structural Consistency

Editor's Note: See Issue-19 (declarations-p) and Issue-20 (annotate-declarations?).

In addition to axioms, OWL 1.1 also provides declarations, which can be used to check the structural consistency of an ontology. In OWL 1.1, it is possible to use a URI for an entity without explicitly stating that an entity with such a name exists. For example, the following is a correct OWL 1.1 ontology:

     SubClassOf( Human Animal )

In this example, the classes Human and Animal are used without explicitly stating that they exist. This is desirable in many situations, since it allows "anyone to say anything about anything," which is consistent with the vision of the Semantic Web. This approach can, however, make it difficult to detect structural errors in ontologies; a typographical error in a class name, for example, simply introduces a new class with a different name. This issue can be addressed by using declarations to check the structural integrity of an ontology. We say that an entity is declared in an ontology O if either O or some ontology O' imported by O contains a declaration axiom for the entity. Note that an ontology may contain multiple declarations for the same entity, and that imported ontologies may do so as well. An ontology O is structurally consistent if each entity occurring in an axiom from the axiom closure of O is declared in O. Note that, by this definition, the check applies also the entities used in annotations; that is, these entities must be properly declared as well for an ontology to be structurally consistent. Note that, although structurally consistency can be a very useful feature in some applications, OWL 1.1 does not require ontologies to be structurally consistent. Thus, an ontology can be used even if it does not contain any declarations. As shown in Figure 19, a declaration is a kind of axiom; this is in order to allow an ontology to be treated as simply a set axioms. A declaration, however, imposes no constraints on the model-theoretic interpretation of an ontology (in the sense of [OWL 1.1 Semantics]).

Entity Declarations in OWL 1.1
Figure 19. Entity Declarations in OWL 1.1

The grammar for declarations is as follows:

declaration := 'Declaration' '(' { annotation } entity ')'

Note that the production for the declaration nonterminal requires an entity and not a URI. Thus, an OWL class should be declared as follows:


This is so that the type of the entity being declared can easily be determined from the syntactic form of the declaration.

[edit] 12 Appendix: Differences from OWL 1.0 Abstract Syntax

OWL 1.1 departs in its conceptual design and in syntax from OWL 1.0 Abstract Syntax. In this section we summarize the differences and explain the rationale behind the changes.

[edit] 12.1 Dropping the Frame-Like Syntax

OWL 1.0 provides a frame-like syntax that allows several aspects of a class, property or individual to be defined in a single axiom. For example, one can write the following axiom in OWL 1.0:

ObjectProperty(partOf inverseOf(containedIn) inverseFunctional transitive
     Label("Specifies that an object is a part of another object.")

This type of axiom may cause problems in practice. In the first place, it bundles many different features of the given object into a single axiom. While this may be convenient when ontologies are being manipulated by hand, it is not convenient for manipulating them programmatically. In fact, most implementations of OWL 1.0 break such axioms apart into several "atomic" axioms, each dealing with only a single feature of the object. However, this may cause problems with round-tripping, as the structure of the ontology may be destroyed in the process. In the second place, this type of axiom is often misinterpreted as a declaration and unique "definition" of the given object. In OWL 1.0, however, objects may be used without being the subject of any such axiom, and there may be many such axioms relating to the same object. Finally, OWL 1.0 does not provide means to annotate axioms, which has proved to be quite useful in practice. These problems are addressed in OWL 1.1 in several ways. First, the frame-like notation has been dropped in favor of a more fine-grained structure of axioms, where each axiom describes just one feature of the given object. Second, OWL 1.1 provides explicit declarations, and an explicit definition of the notion of structural consistency. Finally, all axioms in OWL 1.1 can be annotated, and entity annotation axioms provide means for that. For example, the above mentioned OWL 1.0 axiom can be represented in OWL 1.1 as follows:

     Label("Specifies that an object is a part of another object.")
EquivalentObjectProperties(partOf InverseObjectProperty(containedIn))
TransitiveObjectProperty(Comment("The partOf property is transitive.") partOf)

Although OWL 1.1 is more verbose, this should not be a problem given that most OWL ontologies are created using ontology engineering tools. Moreover, such tools are free to present the information to the user in a more intuitive (possibly frame-like) way.

[edit] 12.2 Inverse Property Expressions

In OWL 1.0, all properties are atomic, but it is possible to assert that one object property is the inverse of another. For example, one can assert the following axiom in OWL 1.0:

ObjectProperty(hasPart inverse isPartOf)

In OWL 1.1, property expressions such as InverseObjectProperty(hasPart) can be used in class expressions, which avoids the need to give a name to every inverse property. If desired, however, names can still be given to inverse properties. For example, the following OWL 1.1 axiom asserts that isPartOf is the inverse of hasPart, and is thus equivalent to the mentioned OWL 1.0 axiom:

EquivalentObjectProperties(InverseObjectProperty(hasPart) isPartOf)

[edit] 12.3 Separating the Vocabulary for Names

Editor's Note: See Issue-17 (role punning), Issue-18 (property typing), Issue-65 (excess vocab) and Issue-69 (punning).

OWL 1.0 relies on the separation of names between concepts, individuals, and object and data properties, but the type of a given name may not be obvious from the context in which it is used. Consider, for example, the following OWL 1.0 axiom:

SubClassOf(Lion restriction(eats someValuesFrom(Animal)))

From this axiom alone, it is not clear how to interpret the class restriction(eats someValuesFrom Animal): one possibility is to treat eats as an object property and Animal as a class, and the other one is to treat eats as a data property and Animal as a datatype. Examining other axioms in the ontology (or in an imported ontology) may make it possible to disambiguate this one, but this is not required in OWL 1.0: an ontology containing only the mentioned axiom is a correct OWL 1.0 ontology in which the intended usage of eats and Animal cannot be disambiguated. Hence, parsing an OWL 1.0 ontology requires not only two passes through the ontology being parsed, but also possibly parsing imported ontologies as well; this makes parser implementation complex and error prone. This problem is addressed in OWL 1.1 by explicitly typing each usage of a name. For example, the above mentioned axiom can be represented in OWL 1.1 as follows:

SubClassOf(Lion ObjectSomeValuesFrom(eats Animal))

This makes it completely clear that eats is intended to be interpreted as an object property and Animal as a class.

[edit] 13 References

[OWL 1.1 Semantics]
OWL 1.1 Web Ontology Language: Model-Theoretic Semantics. Bernardo Cuenca Grau and Boris Motik, eds., 2006.
The Even More Irresistible SROIQ. Ian Horrocks, Oliver Kutz, and Uli Sattler. In Proc. of the 10th Int. Conf. on Principles of Knowledge Representation and Reasoning (KR 2006). AAAI Press, 2006.
[XML Namespaces]
Namespaces in XML 1.0 (Second Edition). Tim Bray, Dave Hollander, Andrew Layman, and Richard Tobin, eds. W3C Recommendation 16 August 2006.
[XML Schema Datatypes]
XML Schema Part 2: Datatypes Second Edition. Paul V. Biron and Ashok Malhotra, eds. W3C Recommendation 28 October 2004.
[RDF Syntax]
RDF/XML Syntax Specification (Revised). Dave Beckett, Editor, W3C Recommendation, 10 February 2004,
RFC 3066 - Tags for the Identification of Languages. H. Alvestrand. IETF, January 2004,
RFC 3987 - Internationalized Resource Identifiers (IRIs). M. Duerst, M. Suignard. IETF, January 2005,
[OWL Semantics and Abstract Syntax]
OWL Web Ontology Language: Semantics and Abstract Syntax Peter F. Patel-Schneider, Patrick Hayes, and Ian Horrocks, eds. W3C Recommendation, 10 February 2004, Latest version available at
CURIE Syntax 1.0: A syntax for expressing Compact URIs. M. Birbeck, S. McCarron, Editors, W3C Working Draft, 26 November 2007,
Turtle - Terse RDF Triple Language. D. Beckett, 20 November 2007,